OPTI ECHO 1 DIME 2 ELEM SEG2;
*
*  OPTI DONN 'barreplast1.dgibi';
*
* GORNET 2003 Janvier   
*
* Unitées Pa, m
*
* Treillis hypertatique
*
*************************************************************
*                       MAILLAGE
*Longueur l
LL = 1.;
*
P1 = 0. 0.  ;
P2 = LL 0.   ;
P3 = 0. (-1.* LL / (3.**(0.5))) ;
P4 = 0. (-1.* LL *  (3.**(0.5))) ;
*
L12 = P1 DROIT 1 P2;
L32 = P3 DROIT 1 P2;
L42 = P4 DROIT 1 P2;
*
TREI1 = L12 ET L32 ET L42;
TRAC QUAL TREI1 ;
*************************************************************
*                       MATERIAU
*                       LINEAIRE
YO1 = 1.E7;
NU1 = 0.3;
RHO1 = 1.E4;
*                       NON LINEAIRE
SIY = 1.E4;
HV = 0.1 * YO1 ;
**************************************************
*                        SECTION
SEC1 =  0.1;
 
**************************************************
*                         MODELE MECANIQUE POUTRE EULER
* IL y a un bug en décharge
MOD1 =  MODL TREI1  MECANIQUE ELASTIQUE PLASTIQUE CINEMATIQUE BARRE;
MAT1 = MATR MOD1 YOUNG YO1 NU NU1 RHO RHO1 
       SIGY SIY H HV;
CAR1 = CARB MOD1 SECT SEC1  ;
*opti donn 5;
MOD1 =  MODL TREI1   MECANIQUE ELASTIQUE PLASTIQUE PARFAIT BARRE;
MAT1 = MATR MOD1 YOUNG YO1 NU NU1 RHO RHO1 
       SIGY SIY  ;
CAR1 = CARB MOD1 SECT SEC1  ;
****************************************************************
* Courbe de traction  en plasticité Sig = E/10 epsi
*     progx =  PROG 0. 0.001  10.;
*     progy =  PROG 0. 10000  1.E7;
*     evT1 = evol manu eps progx sig progy; 
*****************************************************************
*  
*MOD1 =  MODL TREI1 MECANIQUE ELASTIQUE PLASTIQUE ISOTROPE BARRE;
*MAT1 = MATR MOD1 YOUNG YO1 NU NU1 RHO RHO1   'TRAC'  evT1 ;
*CAR1 = CARB MOD1 SECT SEC1  ;
*
MAS1 =  MASSE  MOD1 ( MAT1 ET CAR1) ;                           
RIG1 = RIGI MOD1 ( MAT1 ET CAR1);
*
*
***********************************************************  
*                   CONDITIONS LIMITES  
*DEPLA ROTA UX UY UZ
CL11 = BLOQUE DEPLA   P1;
CL3 = BLOQUE DEPLA   P3;
CL4 = BLOQUE DEPLA   P4;
CL1 = CL11 ET CL3 ET CL4;
***********************************************************
*                  CHARGEMENT LINEAIRE unitaire et tracé
*
*

F1 = FORCE  (  0. -1.   )   P2;
 
VF1 = VECT F1 FX FY  1.;
TRAC TREI1    VF1;
***********************************************************
*                 CHARGEMENT NON  LINEAIRE
*Chargement 1
*AMPFY = 1200.; 
*LI1 = PROG 0.     3.       6.  ;
*LI2 = PROG 0.    AMPFY     0.   ;
*LIS_TPS = PROG 0. PAS 0.06 6.;
*
*Chargement 2
AMPFY = 1200.;
*AMPFY = 1155.;  
LI1 = PROG 0.     6.      ;
LI2 = PROG 0.    AMPFY    ;
LIS_TPS = PROG 0. PAS 0.01 6.;
*
*
EV = EVOL MANU 'TEMPS' LI1 'F(t)' LI2;
CHA1 = CHAR MECA F1 EV;
DESS EV TITRE 'Ftot =  ABS F(t)';
*
*
***********************************************************  
*                  RESOLUTION  ELASTIQUE
DEP1 = RESOU (RIG1 ET CL1) ( F1 );
*
*Deformations
EPS1 = EPSI MOD1 DEP1 CAR1;
EPS2= CHANGER CHPO MOD1 EPS1 'SOMM' ;
*
list eps1;
trac eps1  MOD1 ;
*
*
*Contraintes
SIG1 = SIGMA MOD1 DEP1 (MAT1 ET CAR1);
list SIG1;
* Ruse !!
SIG2 = EXCO SIG1 'EFFX';
trac SIG2 MOD1 ;

opti donn 5;


***********************************************************
*                  RESOLUTION NON LINEAIRE
*

*
*

*
*'DEBPROC' AUTOPILO DELT*'CHPOINT' DELA*'CHPOINT' ZMOD*'MMODEL'
*         ZMAT*'MCHAML' TTT*TABLE ; 
*      NORM1 =     (extraire  delt P2 'UY' )  ;
*FINPROC   NORM1;



TAB1 = TABLE;
TAB1.'MODELE' = MOD1;
TAB1.'CARACTERISTIQUES' = MAT1 ET CAR1;
TAB1.'CHARGEMENT' = CHA1;
TAB1.'BLOCAGES_MECANIQUES' = CL1;
TAB1.'TEMPS_CALCULES' = LIS_TPS ;
TAB1.'TEMPS_SAUVES' = LIS_TPS ;
*
TAB1.'FTOL' = 1.0E-8;
TAB1.'MTOL' = 1.0E-8;
TAB1.'PRECDECHARGE' = 1.0E-8;
TAB1.'PRECISION' = 1.0E-8;
TAB1.'PRECFLEX' = 1.0E-8;
TAB1.'MAXITERATION'= 250;
*
TAB1.'CONVERGENCE_FORCEE' = FAUX; 
*TAB1.'AUTOPAS' = 200;
*TAB1.'AUTOCRIT' = 0.05;
*TAB1.'AUTORESU' = 1;
*TAB1.'AUTOMATIQUE' = VRAI ;
*TAB1.'DELTAITER' = 250;
*TAB1.'PAS_AJUSTE' = VRAI;
*TAB1.'K_TANGENT' = VRAI;
*
* Avec calcul dynamique
*
*TAB1.'DYNAMIQUE' = VRAI ;
*TAB1.'MASSE_CONSTANTE' = MAS1 ;
*
PASAPAS TAB1;
*
*
*list tab1;
*OPTI DONN 5;
*OPTI DONN 3;
************************************************************
*                   VERIFICATION
SI (TAB1.'ERREUR');
 MESS 'Erreur reperee lors de l execution du calcul';
SINON ;
 MESS 'Aucune erreur lors du calcul';

  SI (TAB1.'CONV');
      MESS 'Convergence du calcul';
     SINON  ;
      MESS 'Pas de convergence du 
            calcul pour le nombre d iterations demande';
  FINSI;
FINSI;
************************************************************
*             POST :COURBE DEPLACEMENT - FORCE
* Données TAB1, l'evolution de l'effort (LI1 LI2)                  
************************************************************
TAB2 = TAB1.'DEPLACEMENTS';
NDIM = DIME TAB2  ;
TAB3 = TAB1.'TEMPS';
**
IB = 0;
LIS1 = PROG;
LIS2 = PROG;
*
LIS3 = PROG;
REPETER BOUC1 NDIM  ;
*Deplacement
  DDD =  EXTR  (TAB2.IB) P2 UY;
  LIS2 = INSER LIS2 &BOUC1 (-1.*DDD);
*Temps
DTT =  (TAB3.IB)  ;
LIS1 = INSER LIS1 &BOUC1 DTT; 
*
*Effort impose interpole au temps ddt
FT = IPOL DTT LI1 LI2 ;
*Creation de la liste de l'effort impose
LIS3 =  INSER LIS3 &BOUC1 FT;
IB = IB+1;
FIN BOUC1;
*
*
TITRE 'COURBE DEPLACEMENT - TEMPS';
EV1 = EVOL MANU LIS1 'TEMPS' LIS2 'DEPLACEMENT' ;
DESS EV1;
*
TITRE 'COURBE FORCE - TEMPS';
EV2 = EVOL MANU LIS1 'TEMPS' LIS2 'FORCE';
DESS EV2;
TITRE 'COURBE DEPLACEMENT - FORCE';
EV3 = EVOL MANU LIS2 'DEPLACEMENT' LIS3 'FORCE';
DESS EV3;
***********************************************************
*          TRACE DES DEFORMEES
*FMAX  FMIN  A FAire
*
FMAX = NDIM-10 ;
FMIN = NDIM-1;
CHDEPM = TAB2.FMAX;
CHDEPF = TAB2.FMIN;
DEF0 = DEFO TREI1 CHDEPF 0 BLAN;
DEF1 = DEFO TREI1 CHDEPM 0 ROUGE;
DEF2 = DEFO TREI1 CHDEPF 1 VERT;
*
TITRE 'DEFORMEE DU TREILLIS';
TRAC  (DEF0 ET DEF1);
TITRE 'DEFORMEE DU TREILLIS RELACHE ';
TRAC  (DEF0 ET DEF2);

*